Nhiều bảng tính trong công ty đặt tiêu đề theo chiều ngang: bảng kế hoạch doanh thu xếp các tháng từ trái sang phải, bảng phụ cấp chia cột theo chức vụ. Khi cần lấy một con số như doanh thu Tháng 4, nhiều người dò bằng mắt rồi gõ lại, vừa chậm vừa dễ nhìn nhầm cột. Hàm VLOOKUP quen thuộc chỉ tìm theo cột dọc, nên bạn không dùng trực tiếp được với kiểu bảng này.

Hàm HLOOKUP giải quyết đúng tình huống đó. Bài viết hướng dẫn bạn cú pháp HLOOKUP qua ba ví dụ từ dễ đến khó, chỉ ra ba giới hạn của hàm, rồi giới thiệu hai cách khác là INDEX kết hợp MATCH và XLOOKUP để bạn chọn cách phù hợp cho từng bảng. Số liệu trong bài là ví dụ giả định, và mọi kết quả đã được kiểm tra trên Excel 365.

HLOOKUP là hàm gì?

HLOOKUP là hàm tra cứu theo hàng ngang (chữ H là viết tắt của Horizontal, nghĩa là nằm ngang). Hàm tìm một giá trị ở dòng đầu tiên của bảng, sau đó đi thẳng xuống trong cùng cột và lấy giá trị ở dòng bạn chỉ định. Cách làm này giống cách bạn tra bảng bằng mắt: bạn tìm chữ "Tháng 4" trên dòng tiêu đề rồi nhìn xuống dòng Doanh thu.

VLOOKUP làm việc tương tự nhưng theo chiều dọc: hàm tìm ở cột đầu tiên bên trái rồi lấy giá trị trong cùng dòng. Vì vậy, bạn chọn hàm theo một quy tắc đơn giản:

  • Giá trị cần tìm nằm ở cột đầu tiên bên trái bảng thì bạn dùng VLOOKUP.

  • Giá trị cần tìm nằm ở dòng đầu tiên trên cùng bảng thì bạn dùng HLOOKUP.

Dữ liệu nằm ngang thường xuất hiện ở ba loại bảng. Bảng kế hoạch và báo cáo theo tháng đặt các tháng trên dòng tiêu đề. Bảng giá theo mốc số lượng hoặc theo khu vực dành mỗi mốc một cột. Bảng tham số do phòng nhân sự, kế toán lập (mức phụ cấp, tỷ lệ hoa hồng) thường nằm ngang ở đầu file để in gọn trên một trang. HLOOKUP có mặt trong mọi phiên bản Excel và trong cả Google Sheets.

Hàm HLOOKUP có cú pháp như thế nào?

Cú pháp: =HLOOKUP(lookup_value, table_array, row_index_num, [range_lookup])

Các giá trị trong cặp ngoặc được gọi là đối số. Ba đối số đầu là bắt buộc, còn đối số trong ngoặc vuông có thể bỏ trống.

Đối số

Ý nghĩa

lookup_value

Đây là giá trị cần tìm, ví dụ ô B6 chứa chữ Tháng 4. Giá trị này phải nằm ở dòng đầu tiên của bảng tra cứu.

table_array

Đây là bảng tra cứu, gồm dòng tìm kiếm ở trên cùng và các dòng kết quả bên dưới, ví dụ B1:G4.

row_index_num

Đây là số thứ tự của dòng cần lấy, đếm bên trong bảng tra cứu. Dòng tìm kiếm là dòng số 1.

range_lookup

Đây là kiểu tìm. FALSE (hoặc 0) là khớp chính xác, TRUE (hoặc 1) là khớp gần đúng. Nếu bạn bỏ trống, Excel hiểu là TRUE.

Khớp chính xác nghĩa là Excel chỉ nhận giá trị giống hệt giá trị cần tìm. Khớp gần đúng nghĩa là Excel chấp nhận giá trị gần nhất theo quy tắc riêng, được giải thích ở ví dụ 2. Người mới hay nhầm ở hai điểm:

  1. Số thứ tự dòng được đếm trong bảng tra cứu chứ không phải số dòng của trang tính. Với bảng B5:G8, dòng 5 của trang tính là dòng số 1 của bảng, nên muốn lấy dòng 7 bạn ghi số 3.

  2. Khi bạn bỏ trống đối số cuối, HLOOKUP mặc định tìm gần đúng. Khi tìm theo tên, mã hay tháng, bạn nên luôn ghi FALSE.

Nếu bạn gõ dấu phẩy mà Excel báo lỗi công thức, có thể máy của bạn đang dùng dấu chấm phẩy (;) để ngăn cách đối số theo cài đặt vùng. Khi đó bạn chỉ cần đổi dấu phẩy thành dấu chấm phẩy.

Ví dụ 1: HLOOKUP lấy doanh thu và lợi nhuận theo tháng

Bảng kế hoạch 6 tháng đầu năm nằm ở vùng A1:G4, đơn vị triệu đồng, với số liệu như trong ảnh bên dưới. Dòng 1 chứa tên tháng từ Tháng 1 (ô B1) tới Tháng 6 (ô G1), dòng 2 là doanh thu, dòng 3 là chi phí và dòng 4 là lợi nhuận. Ô B6 chứa tháng cần xem là Tháng 4. Để lấy doanh thu của tháng đó, bạn gõ vào ô B7:

=HLOOKUP(B6,B1:G4,2,FALSE)

Hàm HLOOKUP tìm Tháng 4 ở dòng tiêu đề rồi lấy doanh thu 468 và lợi nhuận 126 trong bảng kế hoạch theo tháng
HLOOKUP tìm Tháng 4 ở dòng 1, rồi lấy giá trị ở dòng thứ 2 và dòng thứ 4 của bảng

Excel tìm chữ Tháng 4 ở dòng đầu tiên của bảng (vùng B1:G1) và thấy ở cột E. Sau đó Excel đi xuống dòng thứ 2 của bảng, tức dòng Doanh thu, và trả về ô E2 = 468. Muốn lấy lợi nhuận, bạn đổi số dòng thành 4: ô B8 dùng =HLOOKUP(B6,B1:G4,4,FALSE) và nhận 126. Khi bạn đổi ô B6 thành Tháng 6, hai ô B7 và B8 tự cập nhật thành 602 và 204.

Nếu tháng cần tìm không có trong bảng, ví dụ Tháng 7, HLOOKUP báo lỗi #N/A. Bạn có thể bọc công thức trong hàm IFERROR. Hàm này trả về giá trị thứ hai trong ngoặc khi công thức bên trong bị lỗi, nên công thức =IFERROR(HLOOKUP("Tháng 7",B1:G4,2,FALSE),"Không có dữ liệu") sẽ hiện chữ "Không có dữ liệu" thay cho #N/A.

Ví dụ 2: HLOOKUP khớp gần đúng tính hoa hồng bậc thang

Khớp gần đúng rất hữu ích khi bạn làm việc với các mức bậc thang. Giả sử công ty trả hoa hồng theo doanh số tháng như sau: dưới 50 triệu đồng được 0%, từ 50 triệu được 2%, từ 100 triệu được 3%, từ 200 triệu được 5% và từ 500 triệu trở lên được 7%.

Bạn chuyển chính sách này thành bảng tham số nằm ngang ở vùng A1:F2. Dòng 1 ghi mức sàn của từng bậc, tức con số nhỏ nhất để đạt bậc đó: 0, 50.000.000, 100.000.000, 200.000.000 và 500.000.000. Dòng 2 ghi tỷ lệ tương ứng. Danh sách nhân viên nằm ở vùng A4:D9 với doanh số ở cột B. Ô C5 tính tỷ lệ bằng công thức dưới đây, ô D5 tính tiền hoa hồng bằng =B5*C5, rồi bạn kéo cả hai ô xuống tới dòng 9.

=HLOOKUP(B5,$B$1:$F$2,2,TRUE)

Hàm HLOOKUP khớp gần đúng tính tỷ lệ và tiền hoa hồng bậc thang theo doanh số nhân viên
Với đối số TRUE, HLOOKUP lấy mức sàn lớn nhất không vượt quá doanh số

Với đối số TRUE, khi dòng 1 không có giá trị bằng đúng doanh số, HLOOKUP lấy giá trị lớn nhất nhưng không vượt quá giá trị cần tìm. Ba trường hợp tiêu biểu trong ảnh cho thấy rõ quy tắc này:

  • Chị Chi đạt 120.000.000 đồng, nên Excel dừng ở mức 100.000.000 và trả về 3%, tiền hoa hồng là 3.600.000 đồng.

  • Anh Dũng đạt đúng 200.000.000 đồng, con số này có sẵn ở dòng 1 nên Excel lấy luôn 5%.

  • Chị Hà đạt 680.000.000 đồng, con số này lớn hơn mọi mức sàn nên Excel lấy mức cuối là 500.000.000 và trả về 7%.

Một công thức HLOOKUP ở đây thay được cho công thức IF lồng 4 tầng (bạn có thể so sánh với cách viết trong bài Hàm IF nhiều điều kiện trong Excel). Khi công ty đổi chính sách, bạn chỉ cần sửa con số trong bảng tham số. Tuy vậy, khớp gần đúng có hai điều kiện bắt buộc:

  1. Dòng đầu tiên phải được sắp xếp tăng dần từ trái sang phải. Trong một lần thử, khi cột mức 100.000.000 (3%) bị đặt trước cột mức 50.000.000 (2%), HLOOKUP trả về 2% cho doanh số 120.000.000 thay vì 3% mà không báo lỗi.

  2. Mức sàn đầu tiên nên là 0, vì giá trị cần tìm nhỏ hơn mọi giá trị ở dòng đầu sẽ làm HLOOKUP báo lỗi #N/A.

Ví dụ 3: HLOOKUP lấy phụ cấp từ bảng tham số nằm ngang

Ví dụ này kết hợp bảng tham số nằm ngang với danh sách nhân viên nằm dọc. Bảng tham số ở vùng A1:E3 có tên chức vụ ở dòng 1 (từ ô B1 tới ô E1), phụ cấp điện thoại ở dòng 2 và phụ cấp xăng xe ở dòng 3. Danh sách nhân viên nằm ở vùng A5:E10, cột B ghi chức vụ. Ô C6 dùng =HLOOKUP(B6,$B$1:$E$3,2,FALSE), ô D6 dùng công thức tương tự với số dòng 3, ô E6 cộng hai khoản bằng =C6+D6. Sau đó bạn kéo vùng C6:E6 xuống tới dòng 10.

Hàm HLOOKUP lấy phụ cấp điện thoại và xăng xe theo chức vụ từ bảng tham số nằm ngang
Bảng tham số nằm ngang, danh sách nhân viên nằm dọc, vùng tra cứu được khóa bằng dấu $

Các dấu $ trong vùng $B$1:$E$3 biến vùng này thành tham chiếu tuyệt đối, nghĩa là vùng giữ nguyên khi bạn kéo công thức sang ô khác. Nếu bạn viết B1:E3 không có dấu $, vùng tra cứu sẽ trượt thành B2:E4 ở ô C7, dòng tên chức vụ nằm ngoài vùng và HLOOKUP báo lỗi #N/A từ dòng 7 trở đi. Để thêm dấu $ nhanh, bạn bôi đen địa chỉ vùng trong thanh công thức rồi nhấn F4. Bạn xem thêm các phím tắt hay dùng trong bài Phím tắt Excel thông dụng.

HLOOKUP có 3 giới hạn nào bạn cần biết?

HLOOKUP dễ học và chạy trên mọi phiên bản Excel, nhưng hàm có ba giới hạn. Hai trong số đó cho ra kết quả sai mà Excel không báo lỗi, nên bạn cần nắm rõ trước khi dùng HLOOKUP trong file quan trọng.

Giới hạn 1: Số thứ tự dòng là một con số cố định

Excel không hiểu số 4 trong ví dụ 1 là "dòng Lợi nhuận", mà chỉ hiểu là "dòng thứ 4 của bảng". Giả sử đồng nghiệp chèn thêm dòng Số đơn hàng vào giữa dòng Doanh thu và dòng Chi phí. Excel tự mở rộng bảng thành B1:G5 và đẩy các ô bên dưới xuống một dòng, nhưng số 4 trong công thức vẫn giữ nguyên. Dòng thứ 4 của bảng lúc này là Chi phí, nên ô Lợi nhuận (giờ là ô B9) hiện 342 thay vì 126.

Chèn thêm dòng Số đơn hàng làm hàm HLOOKUP lấy nhầm chi phí 342 thay vì lợi nhuận 126
Số thứ tự dòng gõ tay không đổi khi bảng có thêm dòng, nên HLOOKUP lấy nhầm số liệu

Con số 342 trông bình thường nên rất khó phát hiện. Cách khắc phục là để hàm MATCH tự tìm số thứ tự dòng. Ô B10 trong ảnh được viết theo cách này từ trước khi chèn dòng, và sau khi chèn, công thức tự cập nhật thành =HLOOKUP(B7,B1:G5,MATCH(A9,A1:A5,0),FALSE). Phần MATCH tìm chữ Lợi nhuận (ô A9) trong vùng A1:A5 và trả về 5, nên kết quả vẫn đúng là 126. Vùng cột A dùng cho MATCH phải bắt đầu cùng dòng với bảng tra cứu (cả hai cùng bắt đầu từ dòng 1) để hai bên đếm dòng giống nhau.

Giới hạn 2: HLOOKUP chỉ tìm ở dòng đầu và chỉ lấy kết quả bên dưới

Giả sử bạn muốn biết tháng nào có lợi nhuận cao nhất. Công thức =MAX(B4:G4) cho biết con số đó là 204, nhưng 204 nằm ở dòng 4 còn tên tháng nằm ở dòng 1 phía trên. HLOOKUP không tìm được ở dòng giữa bảng để lấy kết quả ở dòng phía trên, còn INDEX MATCH và XLOOKUP ở phần sau làm được việc này.

Giới hạn 3: Quên đối số FALSE làm kết quả sai mà không báo lỗi

Khi bạn bỏ trống đối số cuối, HLOOKUP tìm gần đúng. Với dữ liệu chưa sắp xếp hoặc giá trị không có trong bảng, kết quả sẽ sai mà không có cảnh báo. Hai thử nghiệm sau dùng chính dữ liệu trong bài:

  • Công thức =HLOOKUP("Tháng 7",B1:G4,2) trả về 602, tức doanh thu Tháng 6, dù bảng không có Tháng 7.

  • Công thức =HLOOKUP("Phó phòng",B1:E3,2) trên bảng phụ cấp trả về 200.000 của Nhân viên thay vì 500.000, vì tên chức vụ không xếp theo thứ tự chữ cái.

Vì vậy, bạn chỉ dùng TRUE cho bảng bậc thang đã sắp xếp tăng dần như ví dụ 2, còn mọi trường hợp khác bạn luôn ghi FALSE.

INDEX kết hợp MATCH khắc phục giới hạn của HLOOKUP như thế nào?

INDEX và MATCH là hai hàm riêng biệt, mỗi hàm làm một việc đơn giản. Bạn nên hiểu từng hàm trước rồi mới ghép lại.

Hàm INDEX lấy giá trị theo vị trí

Cú pháp: =INDEX(vùng, số dòng, [số cột]). INDEX trả về giá trị nằm ở vị trí bạn chỉ định trong vùng. Với bảng kế hoạch, =INDEX(B2:G2,4) lấy ô thứ 4 của vùng B2:G2 là ô E2, kết quả 468. Công thức =INDEX(B2:G4,3,4) lấy ô ở dòng thứ 3, cột thứ 4 của vùng B2:G4 là ô E4, kết quả 126. Bản thân INDEX không tìm kiếm gì, nên việc tìm ra vị trí là nhiệm vụ của MATCH.

Hàm MATCH tìm vị trí của một giá trị

Cú pháp: =MATCH(giá trị cần tìm, vùng tìm, 0). MATCH tìm giá trị trong một vùng gồm một dòng hoặc một cột, rồi trả về số thứ tự của giá trị đó trong vùng. Ví dụ, =MATCH("Tháng 4",B1:G1,0) trả về 4 và =MATCH("Lợi nhuận",A2:A4,0) trả về 3. Số 0 ở cuối nghĩa là khớp chính xác. Nếu bạn bỏ trống số 0, MATCH cũng mặc định tìm gần đúng giống HLOOKUP.

INDEX và MATCH ghép lại thành công thức tra cứu

Khi đặt MATCH vào vị trí "số dòng" hoặc "số cột" của INDEX, bạn có một công thức tra cứu hoàn chỉnh: MATCH tìm vị trí, INDEX lấy giá trị ở vị trí đó. Ảnh dưới làm từng bước ở ô B7, B8 rồi ghép lại ở ô B9.

Hàm MATCH tìm vị trí của Tháng 4, hàm INDEX lấy doanh thu ở vị trí đó, rồi ghép thành một công thức
MATCH tìm vị trí, INDEX lấy giá trị ở vị trí đó

Ô B7 dùng =MATCH(B6,B1:G1,0) và trả về vị trí 4. Ô B8 dùng =INDEX(B2:G2,B7) để lấy ô thứ 4 của dòng Doanh thu là 468. Ô B9 ghép hai bước thành =INDEX(B2:G2,MATCH(B6,B1:G1,0)). Bạn đọc công thức này từ trong ra ngoài: MATCH chạy trước để tìm vị trí, sau đó INDEX lấy giá trị. So với HLOOKUP, cách viết này có ba điểm khác:

  • Vùng tìm và vùng kết quả được tách riêng: bạn tự chọn dòng để tìm và dòng để lấy kết quả, nên dòng kết quả nằm trên hay dưới đều được.

  • Công thức không có số dòng gõ tay: Excel tự điều chỉnh các vùng khi bảng bị chèn dòng. Trong thử nghiệm ở giới hạn 1, công thức INDEX MATCH vẫn trả về đúng lợi nhuận Tháng 4 là 126.

  • Công thức tìm ngược lên dòng tiêu đề được: =INDEX(B1:G1,MATCH(MAX(B4:G4),B4:G4,0)) tìm lợi nhuận cao nhất ở dòng 4 rồi trả về tên tháng ở dòng 1 là Tháng 6.

INDEX MATCH tra cứu 2 chiều theo cả dòng và cột

Tra cứu 2 chiều nghĩa là bạn tìm theo hai điều kiện cùng lúc: một điều kiện chọn dòng, một điều kiện chọn cột. Ở ví dụ dưới, người xem chọn tháng ở ô B6, chọn chỉ tiêu ở ô B7, và ô B8 tự trả về con số tương ứng nhờ INDEX nhận cả số dòng lẫn số cột:

=INDEX(B2:G4,MATCH(B7,A2:A4,0),MATCH(B6,B1:G1,0))

Tra cứu 2 chiều bằng INDEX kết hợp hai hàm MATCH và bằng XLOOKUP lồng nhau, kết quả chi phí Tháng 5 là 371
Một MATCH chọn dòng, một MATCH chọn cột, INDEX lấy ô giao nhau

Với B6 là Tháng 5 và B7 là Chi phí, MATCH thứ nhất tìm Chi phí trong vùng A2:A4 và trả về 2. MATCH thứ hai tìm Tháng 5 trong vùng B1:G1 và trả về 5. INDEX lấy ô ở dòng 2, cột 5 của vùng B2:G4, tức ô F3 = 371. Bạn để ý các vùng phải khớp nhau: vùng số liệu B2:G4 bắt đầu từ dòng 2 nên vùng chỉ tiêu cũng bắt đầu từ A2, vùng số liệu bắt đầu từ cột B nên dòng tên tháng cũng bắt đầu từ B1.

XLOOKUP gộp tra cứu ngang và dọc vào một hàm

Trên Excel 2021 trở đi và Excel 365, bạn có thêm hàm XLOOKUP dùng chung một cú pháp cho cả bảng dọc lẫn bảng ngang.

Cú pháp: =XLOOKUP(giá trị cần tìm, vùng tìm, vùng kết quả, [nếu không tìm thấy], [kiểu khớp]). Hàm còn đối số thứ sáu là kiểu tìm (từ đầu hay từ cuối vùng), nhưng bài này chưa cần dùng tới.

Giống INDEX MATCH, XLOOKUP tách riêng vùng tìm và vùng kết quả. Với bảng kế hoạch, =XLOOKUP(B6,B1:G1,B2:G2) trả về 468 khi B6 là Tháng 4. Đối số thứ tư cho phép ghi sẵn thông báo khi không tìm thấy, thay cho IFERROR. Công thức =XLOOKUP(B8,B4:G4,B1:G1) tìm lợi nhuận cao nhất ở dòng 4 (ô B8 chứa =MAX(B4:G4)) rồi trả về tên tháng ở dòng 1. Trong ảnh dưới, ô B6 được đổi thành Tháng 9 để bạn thấy thông báo khi không có dữ liệu.

Hàm XLOOKUP tra cứu theo hàng ngang, báo Không có dữ liệu khi không tìm thấy và tìm ngược tháng có lợi nhuận cao nhất
XLOOKUP có sẵn đối số báo không tìm thấy và tìm ngược lên dòng tiêu đề được

XLOOKUP tra cứu 2 chiều bằng cách lồng hai hàm: =XLOOKUP(B7,A2:A4,XLOOKUP(B6,B1:G1,B2:G4)) trả về 371 như ảnh ở phần trước. XLOOKUP bên trong lấy cả cột số liệu của Tháng 5, sau đó XLOOKUP bên ngoài chọn dòng Chi phí trong cột đó.

XLOOKUP mặc định khớp chính xác, nên bạn không lo quên FALSE. Với bảng hoa hồng ở ví dụ 2, bạn dùng kiểu khớp -1, nghĩa là lấy giá trị bằng hoặc nhỏ hơn liền kề: =XLOOKUP(B5,$B$1:$F$1,$B$2:$F$2,,-1). Hai dấu phẩy liền nhau cho biết bạn bỏ trống đối số "nếu không tìm thấy". Công thức cho cùng kết quả với HLOOKUP ở cả 5 nhân viên, và trong thử nghiệm đảo thứ tự mức sàn, XLOOKUP vẫn trả về đúng 3% cho doanh số 120.000.000.

Lưu ý về phiên bản: Excel 2019, 2016 và các bản cũ hơn không có XLOOKUP, nên công thức sẽ báo lỗi #NAME? khi được tính lại trên các máy đó. Bạn xem thêm cách dùng hàm này trong bài Hàm XLOOKUP trong Excel.

Nên dùng HLOOKUP, INDEX MATCH hay XLOOKUP?

Tiêu chí

HLOOKUP

INDEX + MATCH

XLOOKUP

Phiên bản Excel

Hàm chạy trên mọi phiên bản

Hai hàm chạy trên mọi phiên bản

Hàm cần Excel 2021, Excel 365 trở lên

Hướng tìm

Hàm chỉ tìm ở dòng đầu, lấy kết quả bên dưới

Công thức tìm và lấy kết quả ở dòng bất kỳ

Hàm tìm và lấy kết quả ở dòng bất kỳ

Khi bảng bị chèn dòng

Số dòng gõ tay không đổi nên dễ lấy sai

Vùng tự điều chỉnh nên kết quả vẫn đúng

Vùng tự điều chỉnh nên kết quả vẫn đúng

Kiểu khớp mặc định

Hàm khớp gần đúng nếu bỏ trống

MATCH cần số 0 để khớp chính xác

Hàm khớp chính xác

Độ dài công thức

Công thức ngắn, dễ đọc

Công thức dài hơn, cần hiểu hai hàm

Công thức ngắn, có sẵn báo không tìm thấy

Từ bảng so sánh, bạn có thể chọn theo tình huống:

  • Bạn dùng HLOOKUP khi bảng tra cứu nhỏ, ít thay đổi cấu trúc và file cần mở được trên mọi phiên bản Excel, ví dụ bảng phụ cấp hay bảng hoa hồng bậc thang.

  • Bạn dùng INDEX kết hợp MATCH khi cần tìm ngược, cần tra 2 chiều hoặc bảng hay bị chèn dòng, trong khi file vẫn phải chạy trên Excel 2019 trở về trước.

  • Bạn dùng XLOOKUP khi bạn và người nhận file đều dùng Excel 365 hoặc Excel 2021 trở lên.

Bạn hay gặp những lỗi nào khi dùng HLOOKUP?

Bạn thấy

Nguyên nhân

Cách sửa

Lỗi #N/A

Giá trị cần tìm không có ở dòng đầu, hoặc bị dư dấu cách như "Tháng 4 "

Bạn kiểm tra chính tả và dùng TRIM để xóa dấu cách thừa: =HLOOKUP(TRIM(B6),B1:G4,2,FALSE)

Lỗi #N/A

Dòng đầu lưu số dạng chữ (ví dụ năm 2025) còn giá trị cần tìm là số

Bạn chọn các ô đó, bấm biểu tượng chấm than màu vàng và chọn Convert to Number

Lỗi #REF!

Số dòng lớn hơn số dòng của bảng, ví dụ ghi 5 với bảng B1:G4

Bạn sửa số dòng hoặc mở rộng bảng tra cứu

Lỗi #VALUE!

Số dòng nhỏ hơn 1, hoặc giá trị cần tìm dài hơn 255 ký tự

Bạn sửa số dòng. Với chuỗi dài, bạn dùng XLOOKUP vì INDEX MATCH thông thường cũng báo lỗi này

Kết quả sai, không báo lỗi

Công thức thiếu FALSE, bảng chưa sắp xếp khi dùng TRUE, hoặc bảng vừa bị chèn dòng

Bạn ghi FALSE khi tìm chính xác và dùng MATCH thay số dòng gõ tay

Bạn còn thắc mắc gì về hàm HLOOKUP?

HLOOKUP có phân biệt chữ hoa và chữ thường không?

HLOOKUP không phân biệt chữ hoa và chữ thường, nên với bảng kế hoạch ở ví dụ 1, bạn gõ "tháng 4" hay "Tháng 4" đều nhận 468. Giả sử vùng B1:D1 chứa ba mã A-101, a-101, B-201 và vùng B2:D2 chứa doanh thu 200, 250, 330. Công thức =HLOOKUP("a-101",B1:D2,2,FALSE) trả về 200 của mã A-101 vì mã này đứng trước. Khi cần phân biệt, bạn dùng =INDEX(B2:D2,MATCH(TRUE,EXACT(B1:D1,"a-101"),0)) và nhận đúng 250. Trên Excel 2019 trở về trước, bạn nhấn Ctrl + Shift + Enter thay cho Enter, vì đây là công thức mảng (công thức xử lý cả vùng ô cùng lúc).

HLOOKUP có lấy dữ liệu từ sheet khác được không?

HLOOKUP lấy được dữ liệu từ sheet khác. Bạn ghi tên sheet trước vùng tra cứu, ngăn cách bằng dấu chấm than, và đặt tên sheet có dấu cách trong cặp nháy đơn, ví dụ =HLOOKUP("SP02",'Bảng giá'!$B$1:$C$2,2,FALSE). Cách nhanh nhất là khi gõ tới đối số thứ hai, bạn bấm sang sheet kia và quét chọn vùng để Excel tự điền tên sheet.

HLOOKUP có tìm theo một phần nội dung được không?

HLOOKUP tìm được theo một phần nội dung khi bạn dùng ký tự đại diện với kiểu tìm FALSE. Dấu * thay cho một chuỗi ký tự bất kỳ, dấu ? thay cho đúng một ký tự. Ví dụ, =HLOOKUP("Tháng*",B1:G4,2,FALSE) trả về 420 vì Tháng 1 là ô đầu tiên khớp với mẫu. Khi nhiều ô cùng khớp, HLOOKUP lấy ô đầu tiên tính từ trái sang.

Có nên chuyển hết công thức HLOOKUP cũ sang XLOOKUP không?

Bạn không bắt buộc phải chuyển, vì công thức HLOOKUP đang chạy đúng vẫn tiếp tục đúng trên Excel mới. Nhiều file cũ trong công ty vẫn dùng HLOOKUP, nên hiểu rõ hàm này giúp bạn đọc và sửa được các file đó. Bạn chỉ nên viết lại khi bảng hay bị chèn dòng, khi cần tìm ngược, hoặc khi cả nhóm đã dùng Excel 365.

Bạn muốn thành thạo nhóm hàm tra cứu trong Excel?

HLOOKUP, INDEX, MATCH và XLOOKUP thuộc nhóm hàm tra cứu, nhóm hàm bạn sẽ dùng thường xuyên khi ghép dữ liệu từ nhiều bảng. Bạn có thể xem thứ tự học các nhóm hàm trong bài Lộ trình học Excel từ cơ bản đến nâng cao.

Nếu muốn học bài bản cùng người hướng dẫn, bạn có thể tham khảo khóa 30 ngày học và thực hành Excel của Nghề Excel, với 30 buổi luyện tập, hơn 500 bài tập thực tế lấy từ doanh nghiệp và coach đồng hành cùng bạn trong từng buổi.