Bảng hợp đồng lao động của bạn hiện 46027 thay vì ngày ký, hoặc cột ngày xuất từ phần mềm kế toán không chịu đổi kiểu dù bạn đã chọn lại định dạng. Bài viết này hướng dẫn bạn định dạng ngày tháng trong Excel theo dd/mm/yyyy, hiện thứ tiếng Việt, ghép ngày vào câu và sửa ngày đang ở dạng chữ.

Để ô 46027 hiện thành 05/01/2026, bạn chọn ô đó, nhấn Ctrl + 1, chọn Custom, gõ dd/mm/yyyy vào ô Type rồi bấm OK. Nếu ô vẫn đứng yên sau khi bạn đổi định dạng, ô đó đang chứa chữ chứ không phải ngày. Bạn gõ =ISNUMBER(B2) vào một ô trống cùng dòng, ví dụ ô D2, để kiểm tra: kết quả FALSE nghĩa là ô B2 là chữ, và bạn chuyển chữ thành ngày bằng Data > Text to Columns với kiểu DMY.

Ảnh trong bài được chụp trên Excel 365 giao diện tiếng Anh. Windows của máy chụp đặt vùng English (United Kingdom), dùng ngày dạng ngày/tháng/năm (Short date là dd/MM/yyyy) và dấu phẩy ngăn tham số trong công thức. Các ô màu vàng nhạt là nơi bạn định dạng hoặc gõ công thức. Nếu Excel của bạn báo lỗi khi gõ công thức có dấu phẩy, bạn thay dấu phẩy ngăn tham số bằng dấu chấm phẩy, ví dụ =DATE(RIGHT(A2,4),MID(A2,4,2),LEFT(A2,2)) thành =DATE(RIGHT(A2;4);MID(A2;4;2);LEFT(A2;2)).

Vì sao ngày tháng trong Excel lại hiện thành một con số?

Excel lưu mỗi ngày dưới dạng một con số, là số thứ tự của ngày tính từ ngày 1/1/1900. Ngày 05/01/2026 được lưu là 46027, còn định dạng chỉ quyết định con số đó hiện ra thế nào. Khi ô ngày bị chuyển về định dạng General, ví dụ sau khi bạn dán dữ liệu từ nơi khác, ô sẽ hiện nguyên con số.

Bảng ví dụ có ngày ký hợp đồng ở cột C và ngày hết hạn ở cột D. Cả hai cột đang hiện số vì các ô đang ở định dạng General.

Bảng hợp đồng có cột Ngày ký và Ngày hết hạn đang hiện số 46027, 46093, 46174, 46249, 46329
Cột C và cột D chứa ngày thật, nhưng ô đang hiện số thứ tự của ngày

Vì định dạng không đổi giá trị trong ô, các công thức cộng trừ ngày vẫn chạy đúng sau khi bạn đổi định dạng. Bài 15 hàm ngày tháng trong Excel hướng dẫn phần tính toán với các con số này.

Bạn chọn kiểu ngày có sẵn trong Format Cells như thế nào?

Hộp thoại Format Cells có sẵn nhiều kiểu ngày, kể cả kiểu viết tháng bằng tiếng Việt. Bạn làm như sau với cột ngày hết hạn:

  1. Bạn quét chọn vùng D2:D6 rồi nhấn Ctrl + 1.

  2. Trong thẻ Number, bạn chọn Date ở danh sách Category.

  3. Ở ô Locale (location), bạn chọn Vietnamese.

  4. Ở danh sách Type, bạn chọn kiểu 14 Tháng Ba 2012 rồi bấm OK.

Hộp thoại Format Cells mục Date, ô Locale là Vietnamese, con trỏ chuột chỉ vào nút OK
Ô Sample hiện 4 Tháng Giêng 2027, tức ngày đầu tiên trong vùng đã chọn theo kiểu 14 Tháng Ba 2012
Cột D hiện ngày hết hạn có tên tháng tiếng Việt, ô D2 là 4 Tháng Giêng 2027 và ô D6 là 2 Tháng Mười Một 2027
Cột D hiện tên tháng bằng tiếng Việt, còn giá trị trong ô vẫn là con số cũ

Trong danh sách Type của Locale English (United Kingdom), 2 kiểu đầu tiên là *14/03/2012 và *14 March 2012 có dấu sao ở trước. Theo Microsoft, kiểu có dấu sao đổi theo cài đặt ngày giờ của Windows, còn kiểu không có dấu sao thì giữ nguyên trên mọi máy. Nếu bạn cần cố định thứ tự ngày, tháng, năm, bạn dùng mục Custom ở phần sau.

Bạn định dạng ngày tháng dd/mm/yyyy bằng Custom như thế nào?

Mục Custom cho phép bạn tự gõ kiểu ngày. Bạn làm như sau với cột ngày ký:

  1. Bạn quét chọn vùng C2:C6 rồi nhấn Ctrl + 1.

  2. Trong thẻ Number, bạn chọn Custom ở danh sách Category.

  3. Ở ô Type, bạn xóa nội dung cũ, gõ dd/mm/yyyy rồi bấm OK.

Hộp thoại Format Cells mục Custom, ô Type ghi dd/mm/yyyy, ô Sample hiện 05/01/2026
Ô Sample hiện 05/01/2026, tức ngày đầu tiên trong vùng theo kiểu bạn vừa gõ
Cột C hiện ngày ký 05/01/2026, 12/03/2026, 01/06/2026, 15/08/2026, 03/11/2026
Ngày 3 tháng 11 hiện là 03/11/2026 vì mã dd và mm luôn đủ 2 chữ số

Mã dd là ngày có 2 chữ số, mm là tháng có 2 chữ số và yyyy là năm có 4 chữ số. Dấu / giữa các mã là ký tự ngăn cách mà bạn muốn hiện.

Bạn nên biết thêm một điểm khi gửi file cho người khác. Trên máy đặt Short date là dd/MM/yyyy như máy trong bài, mã dd/mm/yyyy trùng với kiểu ngày ngắn của Windows, nên Excel lưu ô thành kiểu ngày ngắn có dấu sao. Khi bạn nhấn Ctrl + 1 lần nữa, hộp thoại chọn sẵn mục Date với kiểu *14/03/2012 thay vì Custom. Nếu người nhận dùng máy đặt tháng trước ngày, ô có thể hiện thành tháng/ngày/năm. Để giữ đúng thứ tự trên mọi máy, bạn gõ dd/mm/yyyy;@ thay cho dd/mm/yyyy, và Excel lưu mã này thành kiểu Custom riêng.

Các mã d, dd, ddd, dddd, m, mm, mmm, yyyy hiển thị ngày như thế nào?

Bảng dưới đây dùng cùng ngày 05/09/2026, là một ngày thứ Bảy. Bạn gõ mã ở cột đầu vào ô Type của mục Custom.

Mã bạn gõ

Ý nghĩa

Ô hiển thị

d

Ngày không thêm số 0

5

dd

Ngày có 2 chữ số

05

ddd

Thứ viết tắt

Sat

dddd

Thứ viết đủ

Saturday

m

Tháng không thêm số 0

9

mm

Tháng có 2 chữ số

09

mmm

Tháng viết tắt

Sep

mmmm

Tháng viết đủ

September

yy

Năm có 2 chữ số

26

yyyy

Năm có 4 chữ số

2026

dd/mm/yyyy

Ngày/tháng/năm

05/09/2026

d/m/yyyy

Ngày/tháng/năm, bỏ số 0 ở đầu

5/9/2026

dd-mm-yyyy

Ngăn bằng dấu gạch ngang

05-09-2026

dd.mm.yyyy

Ngăn bằng dấu chấm

05.09.2026

mmmm yyyy

Tháng và năm

September 2026

"Ngày "dd" tháng "mm" năm "yyyy

Chữ tiếng Việt đặt trong ngoặc kép

Ngày 05 tháng 09 năm 2026

[$-vi-VN]dddd

Thứ tiếng Việt

Thứ Bảy

[$-vi-VN]mmmm

Tháng tiếng Việt

Tháng Chín

Bảng có cột Mã định dạng và cột ngày 05/09/2026 hiển thị theo từng mã
Mỗi ô ở cột B chứa cùng một số 46270, chỉ có mã định dạng là khác nhau

Tên thứ và tên tháng như Sat, Sep đi theo ngôn ngữ của Excel và Windows, nên máy của bạn có thể hiện khác. Chữ bạn muốn giữ nguyên, như "Ngày" hoặc "tháng", phải nằm trong ngoặc kép để Excel không hiểu nhầm thành mã. Nếu bạn định dạng ô có cả giờ, bạn gõ dd/mm/yyyy hh:mm, và ô có ngày 31/10/2026 lúc 14 giờ 30 phút hiện 31/10/2026 14:30. Theo Microsoft, chữ m đứng ngay sau h hoặc hh là phút chứ không phải tháng.

Bạn hiện thứ tiếng Việt bằng mã [$-vi-VN]dddd như thế nào?

Phần [$-vi-VN] báo cho Excel dùng tiếng Việt khi viết tên thứ và tên tháng, dù Excel và Windows của bạn đang dùng tiếng Anh. Bảng lịch giao hàng có ngày giao ở cột B, và bạn muốn mỗi ô hiện kèm thứ.

  1. Bạn quét chọn vùng B2:B6 rồi nhấn Ctrl + 1.

  2. Trong thẻ Number, bạn chọn Custom.

  3. Ở ô Type, bạn gõ [$-vi-VN]dddd, dd/mm/yyyy rồi bấm OK.

Hộp thoại Format Cells mục Custom, ô Type ghi [$-vi-VN]dddd, dd/mm/yyyy, ô Sample hiện Thứ Hai, 07/09/2026
Ô Sample hiện Thứ Hai, 07/09/2026 cho ngày giao đầu tiên
Cột B hiện Thứ Hai, 07/09/2026 đến Thứ Sáu, 18/09/2026
Ngày 13/09/2026 hiện là Chủ Nhật, các ngày khác hiện từ Thứ Hai đến Thứ Bảy

Excel lưu phần [$-vi-VN] thành [$-42A], vì 42A là mã số của tiếng Việt, nên bạn gõ cách nào cũng ra cùng kết quả. Nếu bạn chỉ muốn hiện thứ, bạn gõ [$-vi-VN]dddd. Nếu bạn cần lấy thứ để tính toán, ví dụ đếm số ngày Chủ Nhật, bạn đọc thêm bài xác định thứ trong Excel bằng WEEKDAY.

Phím tắt Ctrl + Shift + # định dạng ngày như thế nào?

Phím tắt Ctrl + Shift + # đổi ô đang chọn sang kiểu ngày có ngày, tháng viết tắt và năm mà không cần mở hộp thoại. Trên bàn phím thường, dấu # nằm ở phím số 3, nên bạn nhấn Ctrl + Shift + 3.

Bảng phiếu nhập kho có ngày nhập ở cột B đang hiện số. Bạn quét chọn vùng B2:B5 rồi nhấn Ctrl + Shift + 3.

Cột Ngày nhập kho hiện 03-Sep-26, 10-Sep-26, 17-Sep-26, 24-Sep-26 sau khi nhấn Ctrl + Shift + 3
Trên máy trong bài, phím tắt hiện ngày 03/09/2026 thành 03-Sep-26. Máy đặt vùng khác có thể hiện 3-Sep-26.

Kiểu này có tên tháng tiếng Anh viết tắt và năm 2 chữ số. Nếu bạn cần dd/mm/yyyy, bạn dùng Custom như phần trên. Phím tắt Ctrl + ; không phải là phím định dạng ngày. Phím này nhập ngày hôm nay vào ô đang chọn, còn Ctrl + Shift + ; nhập giờ hiện tại.

Tại sao không đổi được định dạng ngày tháng trong Excel?

Nguyên nhân thường gặp nhất là ô đang chứa chữ trông giống ngày, ví dụ khi dữ liệu xuất từ phần mềm kế toán hoặc dán từ trang web. Định dạng ngày chỉ có tác dụng với con số, nên ô chữ đứng yên dù bạn chọn kiểu nào.

Bảng ví dụ có ngày chứng từ ở cột B. Trong đó, ô B4 là ngày do kế toán gõ tay, còn các ô khác được dán từ phần mềm. Bạn thử đổi cả cột sang kiểu ngày dài:

  1. Bạn quét chọn vùng B2:B7.

  2. Bạn vào thẻ Home, bấm mũi tên ở ô Number Format trong nhóm Number rồi chọn Long Date.

Danh sách Number Format đang mở trên thẻ Home, con trỏ chuột chỉ vào Long Date
Ô Number Format nằm trong nhóm Number của thẻ Home
Chỉ ô B4 đổi thành 08 October 2026, các ô khác trong cột B vẫn hiện như cũ và căn trái
Chỉ ô B4 đổi kiểu, vì đây là ô duy nhất chứa ngày thật

Bạn nhận biết ô ngày dạng chữ bằng 2 dấu hiệu:

  • Ô chữ nằm sát lề trái, còn ô ngày thật nằm sát lề phải, nếu bạn chưa tự căn lề cho cột.

  • Hàm ISNUMBER trả về FALSE với ô chữ và TRUE với ô số.

Để kiểm tra cả cột, bạn chọn ô D2, gõ công thức sau rồi nhấn Enter:

=ISNUMBER(B2)

Bạn đang gõ vào ô D2 công thức =ISNUMBER(B2)
Hàm ISNUMBER hỏi ô B2 có phải là con số hay không

Sau đó, bạn kéo công thức từ ô D2 xuống ô D7.

Cột D có FALSE ở 5 ô và TRUE ở ô D4
Ô D4 ra TRUE vì ô B4 là ngày thật, các ô còn lại ra FALSE

Hàm ISNUMBER chỉ cho biết ô có phải con số hay không. Ô chứa số 20261025 cũng ra TRUE dù số này không phải ngày, nên bạn xem thêm phần dựng lại ngày bằng hàm DATE ở dưới.

Bạn chuyển ngày dạng chữ thành ngày thật bằng Text to Columns như thế nào?

Lệnh Text to Columns đọc lại chữ trong ô và đổi thành ngày theo thứ tự bạn chọn. Bạn làm như sau:

  1. Bạn quét chọn vùng B2:B7.

  2. Bạn vào thẻ Data và bấm Text to Columns.

  3. Bạn bấm Next 2 lần để tới bước 3.

  4. Ở mục Column data format, bạn chọn Date, chọn DMY trong danh sách bên cạnh rồi bấm Finish.

Hộp thoại Text to Columns bước 3, mục Date đã chọn DMY, con trỏ chuột chỉ vào nút Finish
DMY nghĩa là chữ trong ô viết theo thứ tự ngày, tháng, năm
Cột B hiện ngày dài như 02 October 2026, cột D đều ra TRUE
Sau khi chuyển, cả cột nhận kiểu Long Date đã chọn trước đó và cột D đều ra TRUE

Nếu chữ trong cột viết theo tháng trước ngày, ví dụ 10/25/2026, bạn chọn MDY thay cho DMY. Với kiểu DMY, lệnh này cũng chuyển được các dạng 25.10.2026, 5.9.2026, 25-10-2026 và chữ có dấu cách thừa ở đầu, vì bạn đã báo cho Excel thứ tự ngày, tháng, năm. Lệnh ghi đè kết quả lên cột gốc, nên bạn chép cột gốc sang chỗ khác trước nếu cần giữ lại.

Bạn dựng lại ngày bằng hàm DATE với LEFT, MID, RIGHT như thế nào?

Hàm DATE tạo ngày từ 3 số năm, tháng, ngày theo cú pháp =DATE(year, month, day). Các hàm LEFT, MID, RIGHT lấy từng phần trong chuỗi: LEFT lấy ký tự bên trái, MID lấy ký tự ở giữa và RIGHT lấy ký tự bên phải. Cách này hợp khi bạn cần giữ cột gốc, hoặc khi dữ liệu mới được dán vào hằng tháng.

Bảng đối chiếu có ngày trên sao kê ngân hàng ở cột A, viết dạng 05.10.2026. Bạn chọn ô B2, gõ công thức sau rồi nhấn Enter:

=DATE(RIGHT(A2,4),MID(A2,4,2),LEFT(A2,2))

Bạn đang gõ vào ô B2 công thức =DATE(RIGHT(A2,4),MID(A2,4,2),LEFT(A2,2))
RIGHT lấy 4 ký tự cuối là năm, MID lấy 2 ký tự từ vị trí thứ 4 là tháng, LEFT lấy 2 ký tự đầu là ngày

Ngày trên hóa đơn ở cột C viết liền thành số 8 chữ số, ví dụ 20261003. Bạn chọn ô D2, gõ công thức sau rồi nhấn Enter:

=DATE(LEFT(C2,4),MID(C2,5,2),RIGHT(C2,2))

Bạn đang gõ vào ô D2 công thức =DATE(LEFT(C2,4),MID(C2,5,2),RIGHT(C2,2))
Năm nằm ở 4 ký tự đầu, nên thứ tự LEFT và RIGHT ngược với công thức ở cột B

Sau đó, bạn kéo công thức ở ô B2 xuống ô B5 và công thức ở ô D2 xuống ô D5.

Cột B hiện 05/10/2026 đến 28/10/2026, cột D hiện 03/10/2026 đến 27/10/2026
Hai cột kết quả đều là ngày thật, nên bạn định dạng được theo mọi mã ở phần trên

Công thức này chỉ đúng khi mọi ô có cùng độ dài, ví dụ ngày 5 phải được viết là 05. Nếu ô A2 chứa 5.9.2026, công thức trên trả về 05/12/2025 mà không báo lỗi, vì MID lấy nhầm ".2" làm tháng. Với cột có độ dài khác nhau, bạn dùng Text to Columns ở phần trên. Nếu cột gốc có ô trống, công thức báo lỗi #VALUE!. Khi đó, bạn gõ công thức có bọc thêm IF vào ô B2 thay cho công thức cũ, rồi kéo xuống như trước: =IF(A2="","",DATE(RIGHT(A2,4),MID(A2,4,2),LEFT(A2,2))).

Excel hiểu 03/04 là ngày 3 tháng 4 hay ngày 4 tháng 3?

Excel đọc ngày bạn gõ theo cài đặt vùng của Windows. Máy đặt ngày trước tháng, như máy trong bài, hiểu 03/04/2026 là ngày 3 tháng 4. Máy đặt tháng trước ngày, như cài đặt mặc định English (United States), hiểu cùng chuỗi đó là ngày 4 tháng 3.

Bạn gõ =DAY(A2) vào ô B2, =MONTH(A2) vào ô C2, =ISNUMBER(A2) vào ô D2, rồi kéo cả 3 ô xuống dòng 3. Sau đó, bạn gõ 03/04/2026 vào ô A2 và 10/25/2026 vào ô A3.

Ô A2 hiện 03/04/2026 với ngày 3 tháng 4, ô A3 hiện 10/25/2026 căn trái và báo #VALUE!
Máy ngày/tháng/năm đọc 10/25/2026 thành chữ, vì không có tháng 25

Ô A3 thành chữ vì máy trong bài cần ngày đứng trước tháng. Trường hợp này hay gặp khi bạn mở file CSV của phần mềm nước ngoài: ngày có số ngày từ 13 trở lên thành chữ, còn ngày có số ngày từ 1 đến 12 bị đảo ngày và tháng mà không báo lỗi.

Nếu cả cột viết theo tháng trước ngày, bạn quét chọn A2:A3 và chạy Text to Columns với kiểu MDY. Với ô đã bị đổi thành ngày sai, lệnh này đọc lại ngày theo kiểu ngày ngắn của Windows, ví dụ 03/04/2026, rồi hiểu lại theo thứ tự MDY bạn chọn.

Sau khi chạy Text to Columns với MDY, ô A2 là ngày 4 tháng 3 và ô A3 là ngày 25 tháng 10
Cột B và cột C cho thấy ô A2 thành ngày 4 tháng 3, ô A3 thành ngày 25 tháng 10

Ô A3 sau khi chuyển cũng nhận kiểu dd/mm/yyyy giống ô A2, nên bạn không cần định dạng lại.

Nếu muốn Excel đọc ngày theo kiểu khác, bạn đổi cài đặt vùng của Windows. Trên Windows 10 và Windows 11, bạn mở Control Panel, chọn Clock and Region > Region, rồi đổi ô Short date trong thẻ Formats. Windows viết tháng bằng chữ M hoa, ví dụ dd/MM/yyyy. Thay đổi này áp dụng cho mọi phần mềm trên máy, kể cả kiểu ngày có dấu sao trong Excel.

Bạn ghép ngày vào câu bằng hàm TEXT như thế nào?

Định dạng ô không đi theo giá trị khi bạn nối ngày vào một câu. Bảng công nợ có tên khách ở cột A và hạn thanh toán ở cột B. Bạn chọn ô C2, gõ công thức sau rồi nhấn Enter:

="Hạn thanh toán của "&A2&" là "&B2

Ô C2 đang chọn, thanh công thức có ="Hạn thanh toán của "&A2&" là "&B2, ô C2 hiện Hạn thanh toán của Công ty Minh Phát là 46326
Phép nối lấy giá trị thật của ô B2 là 46326 và bỏ qua định dạng ngày

Bạn bọc ô ngày bằng hàm TEXT để giữ kiểu hiển thị. Hàm TEXT có cú pháp =TEXT(value, format_text), trong đó format_text là mã định dạng đặt trong ngoặc kép. Bạn chọn lại ô C2, gõ công thức sau rồi nhấn Enter:

="Hạn thanh toán của "&A2&" là "&TEXT(B2,"dd/mm/yyyy")

Bạn đang gõ vào ô C2 công thức có TEXT(B2,"dd/mm/yyyy")
Tham số thứ hai của hàm TEXT dùng chính các mã định dạng ở bảng phía trên

Sau đó, bạn kéo công thức từ ô C2 xuống ô C4.

Cột C có 3 câu nhắc hạn với ngày 31/10/2026, 05/11/2026 và 20/11/2026
Ô C2 hiện Hạn thanh toán của Công ty Minh Phát là 31/10/2026

Nếu bạn muốn câu có thêm thứ, bạn đổi mã thành TEXT(B2,"[$-vi-VN]dddd, dd/mm/yyyy"), và ô C2 hiện "Hạn thanh toán của Công ty Minh Phát là Thứ Bảy, 31/10/2026". Kết quả của hàm TEXT là chữ, nên hàm ISNUMBER trả về FALSE và cột này sắp xếp theo thứ tự chữ chứ không theo ngày. Đây cũng là cách đổi ngày sang dạng text: bạn gõ =TEXT(B2,"dd/mm/yyyy") vào ô D2 để có chữ 31/10/2026. Bài chuyển số thành text trong Excel bằng hàm TEXT có thêm nhiều mẫu định dạng.

Bạn tắt việc Excel tự đổi số thành ngày như thế nào?

Excel tự đổi những gì trông giống ngày thành ngày. Ví dụ, trên máy đặt ngày trước tháng như máy trong bài, mã vị trí kệ trong kho như 3-12 bị đổi thành 03-Dec, tức ngày 3 tháng 12, sau khi bạn nhấn Enter. Ở bảng ví dụ, bạn gõ 3-12, 1/2 và 12-5 vào các ô A2, A3, A4 theo cách thường, và Excel đổi cả 3 ô thành ngày.

Để giữ nguyên chữ bạn gõ, bạn định dạng ô thành Text trước khi gõ:

  1. Bạn quét chọn vùng B2:B4.

  2. Bạn vào thẻ Home, bấm mũi tên ở ô Number Format rồi chọn Text.

  3. Bạn gõ lại 3 mã trên vào các ô B2, B3 và B4.

Danh sách Number Format đang mở, con trỏ chuột chỉ vào mục Text
Mục Text nằm cuối danh sách, ngay trên dòng More Number Formats
Cột A hiện 03-Dec, 01-Feb, 12-May, cột B giữ nguyên 3-12, 1/2, 12-5
Cột A gõ thường nên Excel đổi thành ngày, cột B đã định dạng Text nên giữ nguyên

Nếu chỉ cần giữ một ô, bạn gõ dấu nháy đơn trước nội dung, ví dụ '3-12. Dấu nháy không hiện trong ô mà chỉ hiện trên thanh công thức.

Nếu ô đã bị đổi thành ngày, việc chọn lại General hoặc Text không đưa ô về chữ bạn đã gõ. Ví dụ, ô A2 đang hiện 03-Dec chuyển sang Text sẽ hiện 46359, là số thứ tự của ngày 03/12/2026. Bạn cần gõ lại các ô này sau khi đã định dạng Text.

Bạn hay gặp lỗi gì khi định dạng ngày tháng trong Excel?

Lỗi

Nguyên nhân

Cách sửa

Ô hiện #####

Cột quá hẹp để hiện đủ ngày, hoặc ô chứa ngày âm do lấy ngày nhỏ trừ ngày lớn.

Bạn nhấp đúp vào cạnh phải của tên cột để Excel tự nới cột, hoặc kiểm tra lại phép trừ.

Ô ngày hiện số như 46027

Ô đang ở định dạng General.

Bạn nhấn Ctrl + 1, chọn Custom và gõ dd/mm/yyyy. Nếu gửi file cho người khác, bạn gõ dd/mm/yyyy;@.

Đổi định dạng mà ô không đổi

Ô chứa chữ trông giống ngày, =ISNUMBER(B2) trả về FALSE.

Bạn dùng Text to Columns với kiểu DMY, hoặc dựng lại ngày bằng hàm DATE.

Ngày và tháng bị đảo cho nhau

Dữ liệu viết tháng trước ngày, còn Windows đặt ngày trước tháng, hoặc ngược lại.

Bạn chạy Text to Columns với kiểu MDY hoặc DMY đúng theo thứ tự của dữ liệu gốc.

Số 20261025 định dạng ngày ra #####

Số này lớn hơn số thứ tự của ngày 31/12/9999, là ngày cuối cùng Excel hiểu được.

Bạn dùng =DATE(LEFT(C2,4),MID(C2,5,2),RIGHT(C2,2)) hoặc Text to Columns với kiểu YMD.

Câu ghép có ngày hiện thành số

Phép nối lấy giá trị thật của ô và bỏ định dạng.

Bạn bọc ô ngày bằng TEXT(B2,"dd/mm/yyyy").

Excel tự đổi mã 3-12 thành ngày

Excel nhận chuỗi giống ngày và đổi thành ngày.

Bạn định dạng ô thành Text trước khi gõ, hoặc gõ dấu nháy đơn ở đầu.

Bạn muốn học Excel bài bản hơn?

Nếu muốn học bài bản cùng người hướng dẫn, bạn có thể tham khảo khóa 30 ngày học và thực hành Excel của Nghề Excel, với 30 buổi luyện tập, hơn 500 bài tập thực tế lấy từ doanh nghiệp và coach đồng hành cùng bạn trong từng buổi.

Ảnh chụp màn hình sản phẩm Microsoft: Used with permission from Microsoft.