Bạn có danh sách khách hàng tháng 9 và tháng 10, và cần biết khách nào quay lại, khách nào không còn mua. So sánh hai danh sách trong Excel bằng mắt rất dễ sót, nhất là khi hai danh sách không cùng thứ tự.

Trước khi làm, bạn cần xác định rõ bài toán. Bài này có 2 câu hỏi: khách nào có ở cả hai tháng, và khách nào chỉ có ở tháng 9. Mấu chốt là đếm xem mỗi khách tháng 9 xuất hiện bao nhiêu lần trong danh sách tháng 10. Ảnh trong bài được chụp trên Excel 365 giao diện tiếng Anh.

Bài dùng ví dụ với khách tháng 9 ở vùng A2:A11 và khách tháng 10 ở vùng D2:D9. Hai danh sách có số lượng khác nhau, và cùng một khách có thể nằm ở hai dòng khác nhau.

Cách 1: Bạn dùng COUNTIF rồi lọc kết quả

Cách này chạy trên mọi phiên bản Excel và rất dễ kiểm tra.

Bước 1: Bạn đếm số lần xuất hiện. Bạn chọn ô B2, gõ công thức sau rồi nhấn Enter:

=COUNTIF($D$2:$D$9,A2)

Bạn đang gõ vào ô B2 công thức COUNTIF, vùng D2:D9 và ô A2 được tô viền màu
Công thức này đếm số lần khách ở ô A2 xuất hiện trong danh sách tháng 10

Dấu $ giữ nguyên vùng tháng 10 khi bạn kéo công thức. Bạn chọn lại ô B2, đưa chuột tới chấm vuông ở góc dưới bên phải ô, khi con trỏ thành dấu cộng đen mảnh thì kéo xuống ô B11.

Cột B hiện số 0 và số 1 tương ứng với từng khách tháng 9
Số 0 nghĩa là khách không có ở tháng 10, số lớn hơn 0 nghĩa là khách có ở tháng 10

Bước 2: Bạn lọc số 0. Bạn chọn ô A1, mở tab Data rồi bấm Filter. Tiếp theo, bạn bấm mũi tên ở ô B1, bỏ tích (Select All), tích vào số 0 và bấm OK.

Menu lọc của cột B chỉ tích số 0, con trỏ nằm ở góc dưới nút OK
Bạn lọc số 0 để lấy khách chỉ có ở tháng 9

Bảng chỉ còn 5 khách không quay lại ở tháng 10.

Bảng sau khi lọc còn An Phát, Minh Tâm, Sao Mai, Thành Công và Xuân Hòa
Dòng bị lọc sẽ ẩn cả phần tương ứng của danh sách tháng 10 ở cột D, nhưng dữ liệu vẫn còn nguyên

Bước 3: Bạn lấy kết quả ra chỗ khác nếu cần. Bạn quét chọn các tên đang hiện, nhấn Ctrl + C, chuyển sang một sheet mới rồi nhấn Ctrl + V. Bạn không dán vào các cột trống của sheet đang lọc, vì một phần kết quả sẽ rơi vào các dòng đang ẩn.

Muốn lấy khách có ở cả hai tháng, bạn đổi bộ lọc sang tích các số khác 0. Khi làm xong, bạn bấm lại Filter để tắt bộ lọc trước khi thử cách tiếp theo.

Cách 2: Bạn dùng hàm FILTER để tự tách danh sách

Nếu bạn dùng Excel 365 hoặc Excel 2021, hàm FILTER làm cả 3 bước trên chỉ bằng một công thức. Kết quả cũng tự cập nhật khi bạn sửa tên trong hai vùng này. Nếu danh sách có thêm dòng nằm ngoài vùng, bạn cần mở rộng vùng trong công thức.

Bạn chọn ô F2, gõ công thức sau rồi nhấn Enter:

=FILTER(A2:A11,COUNTIF(D2:D9,A2:A11)>0)

Bạn đang gõ vào ô F2 công thức FILTER để lấy khách có ở cả hai tháng
Điều kiện lớn hơn 0 nghĩa là khách có xuất hiện ở tháng 10

Để lấy khách chỉ có ở tháng 9, bạn chọn ô G2, gõ công thức sau rồi nhấn Enter:

=FILTER(A2:A11,COUNTIF(D2:D9,A2:A11)=0)

Cột F liệt kê 5 khách có ở cả hai tháng, cột G liệt kê 5 khách chỉ có ở tháng 9
Mỗi công thức tự tràn kết quả xuống các ô bên dưới

Phần công thức

Phần này làm gì

A2:A11

Đây là danh sách cần lấy kết quả.

COUNTIF(D2:D9,A2:A11)

Hàm đếm từng khách tháng 9 trong danh sách tháng 10, nên trả về 10 con số.

>0 hoặc =0

Phép so sánh chọn các khách có mặt hoặc không có mặt ở tháng 10.

Muốn tìm khách mới của tháng 10, bạn đổi chỗ hai vùng trong công thức và gõ vào một ô trống, ví dụ ô I2: =FILTER(D2:D9,COUNTIF(A2:A11,D2:D9)=0). Kết quả là Đại Dương, Kim Long và Nam Sơn. Các ô phía dưới công thức phải trống. Nếu không, Excel báo lỗi #SPILL!.

Cách 3: Bạn tô màu các khách không còn ở tháng 10

Nếu bạn chỉ muốn nhìn nhanh trên bảng, bạn dùng tô màu tự động. Cách này không tách danh sách ra chỗ khác. Quy tắc dưới đây chỉ tô khách tháng 9, và bạn tạo thêm quy tắc tương tự nếu muốn tô khách mới ở cột D.

  1. Bạn quét chọn A2:A11, bắt đầu từ ô A2.

  2. Bạn mở tab Home, chọn Conditional Formatting, New Rule.

  3. Bạn chọn dòng Use a formula to determine which cells to format.

  4. Bạn gõ công thức sau vào ô công thức:

=COUNTIF($D$2:$D$9,$A2)=0

Hộp thoại New Formatting Rule, ô công thức chứa =COUNTIF($D$2:$D$9,$A2)=0
Quy tắc này tô các khách không có trong danh sách tháng 10
  1. Bạn bấm Format, mở thẻ Fill, chọn một màu rồi bấm OK hai lần.

5 khách không có ở tháng 10 được tô màu trong cột A
Màu tự thay đổi khi bạn sửa một trong hai danh sách

Bạn nên chọn cách nào?

Việc bạn cần làm

Cách nên dùng

Bạn dùng Excel bản cũ, hoặc muốn tự kiểm tra từng bước.

Cách 1

Bạn dùng Excel 365 hoặc Excel 2021 và muốn kết quả tự cập nhật.

Cách 2

Bạn chỉ muốn nhìn nhanh sự khác nhau trên bảng.

Cách 3

Bạn cần lưu ý gì khi so sánh hai danh sách?

  • Dấu cách thừa làm kết quả sai. An Phát và An Phát có dấu cách ở cuối được coi là hai giá trị khác nhau. Bạn nên làm sạch dữ liệu bằng hàm TRIM trước khi so sánh. Hàm TRIM không xóa được khoảng trắng đặc biệt khi dữ liệu được chép từ web.

  • COUNTIF không phân biệt chữ hoa và chữ thường. AN PHÁT và An Phát được đếm là giống nhau.

  • Bạn nên so sánh theo mã nếu có mã. Tên khách có thể trùng hoặc viết khác nhau, còn mã khách hàng thường là duy nhất.

Nếu bạn cần so sánh cả các con số giữa hai bảng, bạn có thể đọc bài so sánh dữ liệu hai bảng trong Excel.

Bạn muốn học Excel bài bản hơn?

Nếu muốn học bài bản cùng người hướng dẫn, bạn có thể tham khảo khóa 30 ngày học và thực hành Excel của Nghề Excel, với 30 buổi luyện tập, hơn 500 bài tập thực tế lấy từ doanh nghiệp và coach đồng hành cùng bạn trong từng buổi.

Ảnh chụp màn hình sản phẩm Microsoft: Used with permission from Microsoft.