File Excel có nhiều sheet khiến bạn mất thời gian bấm qua lại để tìm đúng bảng. Hàm HYPERLINK trong Excel tạo một liên kết bấm được ngay trong ô, nên bạn đi tới sheet khác, mở website hoặc mở file chỉ với một lần bấm.
Điểm mạnh của hàm là liên kết nằm trong công thức, nên có thể ghép từ dữ liệu trong ô và kéo xuống cho cả cột. Ảnh trong bài được chụp trên Excel 365 giao diện tiếng Anh.
Các ví dụ dưới đây gõ công thức vào cột B của sheet Ví dụ, còn hai sheet Doanh thu và Chi phí là nơi các liên kết đi tới. Nếu Excel của bạn báo lỗi khi gõ công thức có dấu phẩy, bạn thay dấu phẩy ngăn tham số bằng dấu chấm phẩy.
Hàm HYPERLINK có cú pháp thế nào?
=HYPERLINK(địa chỉ, [tên hiển thị])
Tham số | Tham số này là gì |
|---|---|
địa chỉ | Đây là nơi liên kết đi tới, viết trong ngoặc kép hoặc lấy từ ô khác. |
tên hiển thị | Đây là chữ hiện trong ô. Nếu bạn bỏ trống, ô sẽ hiện chính địa chỉ. |
Liên kết chỉ mở khi bạn bấm đúng vào phần chữ trong ô. Để chọn ô mà không mở liên kết, bạn bấm vào khoảng trống trong ô, hoặc di chuyển tới ô bằng phím mũi tên.
Ví dụ 1: Bạn mở một website
Bạn chọn ô B2, gõ công thức sau rồi nhấn Enter:
=HYPERLINK("https://blog.ngheexcel.com",A2)

Ô B2 hiện chữ "Blog Nghề Excel". Địa chỉ website phải có đủ phần https://.
Ví dụ 2: Bạn đi tới một ô ở sheet khác
Để đi tới một vị trí trong cùng file, bạn thêm dấu # trước địa chỉ. Bạn chọn ô B3, gõ công thức sau rồi nhấn Enter:
=HYPERLINK("#'Doanh thu'!B2",A3)
Tên sheet Doanh thu có dấu cách nên phải nằm trong dấu nháy đơn. Khi bạn rê chuột lên ô, Excel hiện địa chỉ của liên kết.

Bạn bấm vào chữ trong ô B3. Excel chuyển sang sheet Doanh thu và chọn ô B2.

Ví dụ 3: Bạn đi tới một vùng có tên
Nếu vùng dữ liệu đã được đặt tên, liên kết vẫn đúng ngay cả khi bảng bị dời đi chỗ khác. Ví dụ này dùng vùng A2:B4 của sheet Doanh thu, đã được đặt tên là DoanhThuQuy4. Bạn quay lại sheet Ví dụ, chọn ô B4, gõ công thức sau rồi nhấn Enter:
=HYPERLINK("#DoanhThuQuy4",A4)
Khi bạn bấm vào chữ trong ô B4, Excel chuyển sang sheet Doanh thu và chọn cả vùng A2:B4.

Ví dụ 4: Bạn tạo mục lục sheet bằng cách ghép chuỗi
Đây là ứng dụng hữu ích nhất của hàm này. Tên sheet nằm trong ô A5, và bạn ghép tên đó vào địa chỉ. Bạn quay lại sheet Ví dụ, chọn ô B5, gõ công thức sau rồi nhấn Enter:
=HYPERLINK("#'"&A5&"'!A1",A5)

Phần công thức | Phần này làm gì |
|---|---|
| Phần này mở đầu địa chỉ bằng dấu |
| Phần này ghép tên sheet lấy từ ô A5. |
| Phần này đóng dấu nháy đơn và chỉ tới ô A1 của sheet đó. |
Bạn chọn ô B5 bằng cách bấm vào khoảng trống trong ô, đưa chuột tới chấm vuông ở góc dưới bên phải ô, khi con trỏ thành dấu cộng đen mảnh thì kéo xuống ô B6. Mỗi dòng đi tới đúng sheet có tên trong cột A. Trong file thật, bạn liệt kê tên các sheet thành một cột rồi kéo công thức xuống hết cột để có mục lục.
Ví dụ 5: Bạn tạo link gửi email
Bạn dùng tiền tố mailto: để mở ứng dụng thư với địa chỉ người nhận điền sẵn. Bạn chọn ô B7, gõ công thức sau rồi nhấn Enter:
=HYPERLINK("mailto:"&A7&"?subject=Bao cao thang 10","Gửi mail")

Khi bạn bấm vào chữ trong ô, ứng dụng thư mặc định trên máy sẽ mở một thư mới. Tiêu đề thư nên viết không dấu vì một số ứng dụng thư đọc sai chữ có dấu. Máy chưa cài ứng dụng thư thì liên kết này không mở được gì.
Ví dụ 6: Bạn mở một file trên máy
Bạn đưa đường dẫn đầy đủ của file vào công thức. Bạn chọn ô B8, gõ công thức sau rồi nhấn Enter:
=HYPERLINK("C:\Bao-cao\Thang-10.xlsx",A8)

Đường dẫn trong ví dụ chỉ là mẫu, nên bạn cần thay bằng đường dẫn của một file có thật. Windows có thể hiện cảnh báo bảo mật trước khi mở file. Khi bạn gửi file cho người khác, liên kết chỉ chạy nếu máy họ có đúng đường dẫn đó.
Sau 6 ví dụ, cột B của bạn trông như sau:

Bạn đổi nhiều liên kết cùng lúc như thế nào?
Khi thư mục hoặc tên file thay đổi, bạn không cần sửa từng công thức. Bạn nhấn Ctrl + H, gõ phần cũ vào ô Find what, gõ phần mới vào ô Replace with rồi bấm Replace All. Ví dụ, bạn có thể thay Thang-10 bằng Thang-11. Công thức ô B8 đổi theo, còn chữ hiển thị lấy từ ô A8 nên bạn sửa thêm ô đó.

Vì sao hàm HYPERLINK báo lỗi khi bấm?
Thông báo Reference isn't valid thường xuất hiện khi địa chỉ trong cùng file bị sai. Bạn có thể thử bằng cách gõ công thức sau vào ô D3. Công thức này thiếu dấu nháy đơn quanh tên sheet có dấu cách:
=HYPERLINK("#Doanh thu!B2","Link thiếu dấu nháy")

Lỗi bạn gặp | Nguyên nhân | Cách sửa |
|---|---|---|
Excel báo Reference isn't valid. | Địa chỉ sai tên sheet, thiếu dấu nháy đơn hoặc sheet đã bị xóa. | Bạn kiểm tra tên sheet và thêm dấu nháy đơn. |
Excel báo Cannot open the specified file. | Đường dẫn sai, file đã bị đổi tên hay dời đi, hoặc địa chỉ trong cùng file thiếu dấu | Bạn kiểm tra lại đường dẫn và thêm dấu |
Ô báo lỗi | Địa chỉ dài quá 255 ký tự. | Bạn rút ngắn địa chỉ. |
Bạn có thể xem thêm các hàm thường dùng trong bài 16 hàm Excel cơ bản dân văn phòng nên biết.
Bạn muốn học Excel bài bản hơn?
Nếu muốn học bài bản cùng người hướng dẫn, bạn có thể tham khảo khóa 30 ngày học và thực hành Excel của Nghề Excel, với 30 buổi luyện tập, hơn 500 bài tập thực tế lấy từ doanh nghiệp và coach đồng hành cùng bạn trong từng buổi.
Ảnh chụp màn hình sản phẩm Microsoft: Used with permission from Microsoft.